Neat SQL stored procedures

I liked this site http://vyaskn.tripod.com/code.htm and especially the stored proc (http://vyaskn.tripod.com/code/generate_inserts_2005.txt) which scripts existing data as insert statements:

SET NOCOUNT ON
GO

PRINT 'Using Master database'
USE master
GO

PRINT 'Checking for the existence of this procedure'
IF (SELECT OBJECT_ID('sp_generate_inserts','P')) IS NOT NULL --means, the procedure already exists
	BEGIN
		PRINT 'Procedure already exists. So, dropping it'
		DROP PROC sp_generate_inserts
	END
GO

CREATE PROC sp_generate_inserts
(
	@table_name varchar(776),  		-- The table/view for which the INSERT statements will be generated using the existing data
	@target_table varchar(776) = NULL, 	-- Use this parameter to specify a different table name into which the data will be inserted
	@include_column_list bit = 1,		-- Use this parameter to include/ommit column list in the generated INSERT statement
	@from varchar(800) = NULL, 		-- Use this parameter to filter the rows based on a filter condition (using WHERE)
	@include_timestamp bit = 0, 		-- Specify 1 for this parameter, if you want to include the TIMESTAMP/ROWVERSION column's data in the INSERT statement
	@debug_mode bit = 0,			-- If @debug_mode is set to 1, the SQL statements constructed by this procedure will be printed for later examination
	@owner varchar(64) = NULL,		-- Use this parameter if you are not the owner of the table
	@ommit_images bit = 0,			-- Use this parameter to generate INSERT statements by omitting the 'image' columns
	@ommit_identity bit = 0,		-- Use this parameter to ommit the identity columns
	@top int = NULL,			-- Use this parameter to generate INSERT statements only for the TOP n rows
	@cols_to_include varchar(8000) = NULL,	-- List of columns to be included in the INSERT statement
	@cols_to_exclude varchar(8000) = NULL,	-- List of columns to be excluded from the INSERT statement
	@disable_constraints bit = 0,		-- When 1, disables foreign key constraints and enables them after the INSERT statements
	@ommit_computed_cols bit = 0		-- When 1, computed columns will not be included in the INSERT statement
	
)
AS
BEGIN

/***********************************************************************************************************
Procedure:	sp_generate_inserts  (Build 22) 
		(Copyright © 2002 Narayana Vyas Kondreddi. All rights reserved.)
                                          
Purpose:	To generate INSERT statements from existing data. 
		These INSERTS can be executed to regenerate the data at some other location.
		This procedure is also useful to create a database setup, where in you can 
		script your data along with your table definitions.

Written by:	Narayana Vyas Kondreddi
	        http://vyaskn.tripod.com

Acknowledgements:
		Divya Kalra	-- For beta testing
		Mark Charsley	-- For reporting a problem with scripting uniqueidentifier columns with NULL values
		Artur Zeygman	-- For helping me simplify a bit of code for handling non-dbo owned tables
		Joris Laperre   -- For reporting a regression bug in handling text/ntext columns

Tested on: 	SQL Server 7.0 and SQL Server 2000 and SQL Server 2005

Date created:	January 17th 2001 21:52 GMT

Date modified:	May 1st 2002 19:50 GMT

Email: 		vyaskn@hotmail.com

NOTE:		This procedure may not work with tables with too many columns.
		Results can be unpredictable with huge text columns or SQL Server 2000's sql_variant data types
		Whenever possible, Use @include_column_list parameter to ommit column list in the INSERT statement, for better results
		IMPORTANT: This procedure is not tested with internation data (Extended characters or Unicode). If needed
		you might want to convert the datatypes of character variables in this procedure to their respective unicode counterparts
		like nchar and nvarchar

		ALSO NOTE THAT THIS PROCEDURE IS NOT UPDATED TO WORK WITH NEW DATA TYPES INTRODUCED IN SQL SERVER 2005 / YUKON
		

Example 1:	To generate INSERT statements for table 'titles':
		
		EXEC sp_generate_inserts 'titles'

Example 2: 	To ommit the column list in the INSERT statement: (Column list is included by default)
		IMPORTANT: If you have too many columns, you are advised to ommit column list, as shown below,
		to avoid erroneous results
		
		EXEC sp_generate_inserts 'titles', @include_column_list = 0

Example 3:	To generate INSERT statements for 'titlesCopy' table from 'titles' table:

		EXEC sp_generate_inserts 'titles', 'titlesCopy'

Example 4:	To generate INSERT statements for 'titles' table for only those titles 
		which contain the word 'Computer' in them:
		NOTE: Do not complicate the FROM or WHERE clause here. It's assumed that you are good with T-SQL if you are using this parameter

		EXEC sp_generate_inserts 'titles', @from = "from titles where title like '%Computer%'"

Example 5: 	To specify that you want to include TIMESTAMP column's data as well in the INSERT statement:
		(By default TIMESTAMP column's data is not scripted)

		EXEC sp_generate_inserts 'titles', @include_timestamp = 1

Example 6:	To print the debug information:
  
		EXEC sp_generate_inserts 'titles', @debug_mode = 1

Example 7: 	If you are not the owner of the table, use @owner parameter to specify the owner name
		To use this option, you must have SELECT permissions on that table

		EXEC sp_generate_inserts Nickstable, @owner = 'Nick'

Example 8: 	To generate INSERT statements for the rest of the columns excluding images
		When using this otion, DO NOT set @include_column_list parameter to 0.

		EXEC sp_generate_inserts imgtable, @ommit_images = 1

Example 9: 	To generate INSERT statements excluding (ommiting) IDENTITY columns:
		(By default IDENTITY columns are included in the INSERT statement)

		EXEC sp_generate_inserts mytable, @ommit_identity = 1

Example 10: 	To generate INSERT statements for the TOP 10 rows in the table:
		
		EXEC sp_generate_inserts mytable, @top = 10

Example 11: 	To generate INSERT statements with only those columns you want:
		
		EXEC sp_generate_inserts titles, @cols_to_include = "'title','title_id','au_id'"

Example 12: 	To generate INSERT statements by omitting certain columns:
		
		EXEC sp_generate_inserts titles, @cols_to_exclude = "'title','title_id','au_id'"

Example 13:	To avoid checking the foreign key constraints while loading data with INSERT statements:
		
		EXEC sp_generate_inserts titles, @disable_constraints = 1

Example 14: 	To exclude computed columns from the INSERT statement:
		EXEC sp_generate_inserts MyTable, @ommit_computed_cols = 1
***********************************************************************************************************/

SET NOCOUNT ON

--Making sure user only uses either @cols_to_include or @cols_to_exclude
IF ((@cols_to_include IS NOT NULL) AND (@cols_to_exclude IS NOT NULL))
	BEGIN
		RAISERROR('Use either @cols_to_include or @cols_to_exclude. Do not use both the parameters at once',16,1)
		RETURN -1 --Failure. Reason: Both @cols_to_include and @cols_to_exclude parameters are specified
	END

--Making sure the @cols_to_include and @cols_to_exclude parameters are receiving values in proper format
IF ((@cols_to_include IS NOT NULL) AND (PATINDEX('''%''',@cols_to_include) = 0))
	BEGIN
		RAISERROR('Invalid use of @cols_to_include property',16,1)
		PRINT 'Specify column names surrounded by single quotes and separated by commas'
		PRINT 'Eg: EXEC sp_generate_inserts titles, @cols_to_include = "''title_id'',''title''"'
		RETURN -1 --Failure. Reason: Invalid use of @cols_to_include property
	END

IF ((@cols_to_exclude IS NOT NULL) AND (PATINDEX('''%''',@cols_to_exclude) = 0))
	BEGIN
		RAISERROR('Invalid use of @cols_to_exclude property',16,1)
		PRINT 'Specify column names surrounded by single quotes and separated by commas'
		PRINT 'Eg: EXEC sp_generate_inserts titles, @cols_to_exclude = "''title_id'',''title''"'
		RETURN -1 --Failure. Reason: Invalid use of @cols_to_exclude property
	END


--Checking to see if the database name is specified along wih the table name
--Your database context should be local to the table for which you want to generate INSERT statements
--specifying the database name is not allowed
IF (PARSENAME(@table_name,3)) IS NOT NULL
	BEGIN
		RAISERROR('Do not specify the database name. Be in the required database and just specify the table name.',16,1)
		RETURN -1 --Failure. Reason: Database name is specified along with the table name, which is not allowed
	END

--Checking for the existence of 'user table' or 'view'
--This procedure is not written to work on system tables
--To script the data in system tables, just create a view on the system tables and script the view instead

IF @owner IS NULL
	BEGIN
		IF ((OBJECT_ID(@table_name,'U') IS NULL) AND (OBJECT_ID(@table_name,'V') IS NULL)) 
			BEGIN
				RAISERROR('User table or view not found.',16,1)
				PRINT 'You may see this error, if you are not the owner of this table or view. In that case use @owner parameter to specify the owner name.'
				PRINT 'Make sure you have SELECT permission on that table or view.'
				RETURN -1 --Failure. Reason: There is no user table or view with this name
			END
	END
ELSE
	BEGIN
		IF NOT EXISTS (SELECT 1 FROM INFORMATION_SCHEMA.TABLES WHERE TABLE_NAME = @table_name AND (TABLE_TYPE = 'BASE TABLE' OR TABLE_TYPE = 'VIEW') AND TABLE_SCHEMA = @owner)
			BEGIN
				RAISERROR('User table or view not found.',16,1)
				PRINT 'You may see this error, if you are not the owner of this table. In that case use @owner parameter to specify the owner name.'
				PRINT 'Make sure you have SELECT permission on that table or view.'
				RETURN -1 --Failure. Reason: There is no user table or view with this name		
			END
	END

--Variable declarations
DECLARE		@Column_ID int, 		
		@Column_List varchar(8000), 
		@Column_Name varchar(128), 
		@Start_Insert varchar(786), 
		@Data_Type varchar(128), 
		@Actual_Values varchar(8000),	--This is the string that will be finally executed to generate INSERT statements
		@IDN varchar(128)		--Will contain the IDENTITY column's name in the table

--Variable Initialization
SET @IDN = ''
SET @Column_ID = 0
SET @Column_Name = ''
SET @Column_List = ''
SET @Actual_Values = ''

IF @owner IS NULL 
	BEGIN
		SET @Start_Insert = 'INSERT INTO ' + '[' + RTRIM(COALESCE(@target_table,@table_name)) + ']' 
	END
ELSE
	BEGIN
		SET @Start_Insert = 'INSERT ' + '[' + LTRIM(RTRIM(@owner)) + '].' + '[' + RTRIM(COALESCE(@target_table,@table_name)) + ']' 		
	END


--To get the first column's ID

SELECT	@Column_ID = MIN(ORDINAL_POSITION) 	
FROM	INFORMATION_SCHEMA.COLUMNS (NOLOCK) 
WHERE 	TABLE_NAME = @table_name AND
(@owner IS NULL OR TABLE_SCHEMA = @owner)



--Loop through all the columns of the table, to get the column names and their data types
WHILE @Column_ID IS NOT NULL
	BEGIN
		SELECT 	@Column_Name = QUOTENAME(COLUMN_NAME), 
		@Data_Type = DATA_TYPE 
		FROM 	INFORMATION_SCHEMA.COLUMNS (NOLOCK) 
		WHERE 	ORDINAL_POSITION = @Column_ID AND 
		TABLE_NAME = @table_name AND
		(@owner IS NULL OR TABLE_SCHEMA = @owner)



		IF @cols_to_include IS NOT NULL --Selecting only user specified columns
		BEGIN
			IF CHARINDEX( '''' + SUBSTRING(@Column_Name,2,LEN(@Column_Name)-2) + '''',@cols_to_include) = 0 
			BEGIN
				GOTO SKIP_LOOP
			END
		END

		IF @cols_to_exclude IS NOT NULL --Selecting only user specified columns
		BEGIN
			IF CHARINDEX( '''' + SUBSTRING(@Column_Name,2,LEN(@Column_Name)-2) + '''',@cols_to_exclude) <> 0 
			BEGIN
				GOTO SKIP_LOOP
			END
		END

		--Making sure to output SET IDENTITY_INSERT ON/OFF in case the table has an IDENTITY column
		IF (SELECT COLUMNPROPERTY( OBJECT_ID(QUOTENAME(COALESCE(@owner,USER_NAME())) + '.' + @table_name),SUBSTRING(@Column_Name,2,LEN(@Column_Name) - 2),'IsIdentity')) = 1 
		BEGIN
			IF @ommit_identity = 0 --Determing whether to include or exclude the IDENTITY column
				SET @IDN = @Column_Name
			ELSE
				GOTO SKIP_LOOP			
		END
		
		--Making sure whether to output computed columns or not
		IF @ommit_computed_cols = 1
		BEGIN
			IF (SELECT COLUMNPROPERTY( OBJECT_ID(QUOTENAME(COALESCE(@owner,USER_NAME())) + '.' + @table_name),SUBSTRING(@Column_Name,2,LEN(@Column_Name) - 2),'IsComputed')) = 1 
			BEGIN
				GOTO SKIP_LOOP					
			END
		END
		
		--Tables with columns of IMAGE data type are not supported for obvious reasons
		IF(@Data_Type in ('image'))
			BEGIN
				IF (@ommit_images = 0)
					BEGIN
						RAISERROR('Tables with image columns are not supported.',16,1)
						PRINT 'Use @ommit_images = 1 parameter to generate INSERTs for the rest of the columns.'
						PRINT 'DO NOT ommit Column List in the INSERT statements. If you ommit column list using @include_column_list=0, the generated INSERTs will fail.'
						RETURN -1 --Failure. Reason: There is a column with image data type
					END
				ELSE
					BEGIN
					GOTO SKIP_LOOP
					END
			END

		--Determining the data type of the column and depending on the data type, the VALUES part of
		--the INSERT statement is generated. Care is taken to handle columns with NULL values. Also
		--making sure, not to lose any data from flot, real, money, smallmomey, datetime columns
		SET @Actual_Values = @Actual_Values  +
		CASE 
			WHEN @Data_Type IN ('char','varchar','nchar','nvarchar') 
				THEN 
					'COALESCE('''''''' + REPLACE(RTRIM(' + @Column_Name + '),'''''''','''''''''''')+'''''''',''NULL'')'
			WHEN @Data_Type IN ('datetime','smalldatetime') 
				THEN 
					'COALESCE('''''''' + RTRIM(CONVERT(char,' + @Column_Name + ',109))+'''''''',''NULL'')'
			WHEN @Data_Type IN ('uniqueidentifier') 
				THEN  
					'COALESCE('''''''' + REPLACE(CONVERT(char(255),RTRIM(' + @Column_Name + ')),'''''''','''''''''''')+'''''''',''NULL'')'
			WHEN @Data_Type IN ('text','ntext') 
				THEN  
					'COALESCE('''''''' + REPLACE(CONVERT(char(8000),' + @Column_Name + '),'''''''','''''''''''')+'''''''',''NULL'')'					
			WHEN @Data_Type IN ('binary','varbinary') 
				THEN  
					'COALESCE(RTRIM(CONVERT(char,' + 'CONVERT(int,' + @Column_Name + '))),''NULL'')'  
			WHEN @Data_Type IN ('timestamp','rowversion') 
				THEN  
					CASE 
						WHEN @include_timestamp = 0 
							THEN 
								'''DEFAULT''' 
							ELSE 
								'COALESCE(RTRIM(CONVERT(char,' + 'CONVERT(int,' + @Column_Name + '))),''NULL'')'  
					END
			WHEN @Data_Type IN ('float','real','money','smallmoney')
				THEN
					'COALESCE(LTRIM(RTRIM(' + 'CONVERT(char, ' +  @Column_Name  + ',2)' + ')),''NULL'')' 
			ELSE 
				'COALESCE(LTRIM(RTRIM(' + 'CONVERT(char, ' +  @Column_Name  + ')' + ')),''NULL'')' 
		END   + '+' +  ''',''' + ' + '
		
		--Generating the column list for the INSERT statement
		SET @Column_List = @Column_List +  @Column_Name + ','	

		SKIP_LOOP: --The label used in GOTO

		SELECT 	@Column_ID = MIN(ORDINAL_POSITION) 
		FROM 	INFORMATION_SCHEMA.COLUMNS (NOLOCK) 
		WHERE 	TABLE_NAME = @table_name AND 
		ORDINAL_POSITION > @Column_ID AND
		(@owner IS NULL OR TABLE_SCHEMA = @owner)


	--Loop ends here!
	END

--To get rid of the extra characters that got concatenated during the last run through the loop
SET @Column_List = LEFT(@Column_List,len(@Column_List) - 1)
SET @Actual_Values = LEFT(@Actual_Values,len(@Actual_Values) - 6)

IF LTRIM(@Column_List) = '' 
	BEGIN
		RAISERROR('No columns to select. There should at least be one column to generate the output',16,1)
		RETURN -1 --Failure. Reason: Looks like all the columns are ommitted using the @cols_to_exclude parameter
	END

--Forming the final string that will be executed, to output the INSERT statements
IF (@include_column_list <> 0)
	BEGIN
		SET @Actual_Values = 
			'SELECT ' +  
			CASE WHEN @top IS NULL OR @top < 0 THEN '' ELSE ' TOP ' + LTRIM(STR(@top)) + ' ' END + 
			'''' + RTRIM(@Start_Insert) + 
			' ''+' + '''(' + RTRIM(@Column_List) +  '''+' + ''')''' + 
			' +''VALUES(''+ ' +  @Actual_Values  + '+'')''' + ' ' + 
			COALESCE(@from,' FROM ' + CASE WHEN @owner IS NULL THEN '' ELSE '[' + LTRIM(RTRIM(@owner)) + '].' END + '[' + rtrim(@table_name) + ']' + '(NOLOCK)')
	END
ELSE IF (@include_column_list = 0)
	BEGIN
		SET @Actual_Values = 
			'SELECT ' + 
			CASE WHEN @top IS NULL OR @top < 0 THEN '' ELSE ' TOP ' + LTRIM(STR(@top)) + ' ' END + 
			'''' + RTRIM(@Start_Insert) + 
			' '' +''VALUES(''+ ' +  @Actual_Values + '+'')''' + ' ' + 
			COALESCE(@from,' FROM ' + CASE WHEN @owner IS NULL THEN '' ELSE '[' + LTRIM(RTRIM(@owner)) + '].' END + '[' + rtrim(@table_name) + ']' + '(NOLOCK)')
	END	

--Determining whether to ouput any debug information
IF @debug_mode =1
	BEGIN
		PRINT '/*****START OF DEBUG INFORMATION*****'
		PRINT 'Beginning of the INSERT statement:'
		PRINT @Start_Insert
		PRINT ''
		PRINT 'The column list:'
		PRINT @Column_List
		PRINT ''
		PRINT 'The SELECT statement executed to generate the INSERTs'
		PRINT @Actual_Values
		PRINT ''
		PRINT '*****END OF DEBUG INFORMATION*****/'
		PRINT ''
	END
		
PRINT '--INSERTs generated by ''sp_generate_inserts'' stored procedure written by Vyas'
PRINT '--Build number: 22'
PRINT '--Problems/Suggestions? Contact Vyas @ vyaskn@hotmail.com'
PRINT '--http://vyaskn.tripod.com'
PRINT ''
PRINT 'SET NOCOUNT ON'
PRINT ''


--Determining whether to print IDENTITY_INSERT or not
IF (@IDN <> '')
	BEGIN
		PRINT 'SET IDENTITY_INSERT ' + QUOTENAME(COALESCE(@owner,USER_NAME())) + '.' + QUOTENAME(@table_name) + ' ON'
		PRINT 'GO'
		PRINT ''
	END


IF @disable_constraints = 1 AND (OBJECT_ID(QUOTENAME(COALESCE(@owner,USER_NAME())) + '.' + @table_name, 'U') IS NOT NULL)
	BEGIN
		IF @owner IS NULL
			BEGIN
				SELECT 	'ALTER TABLE ' + QUOTENAME(COALESCE(@target_table, @table_name)) + ' NOCHECK CONSTRAINT ALL' AS '--Code to disable constraints temporarily'
			END
		ELSE
			BEGIN
				SELECT 	'ALTER TABLE ' + QUOTENAME(@owner) + '.' + QUOTENAME(COALESCE(@target_table, @table_name)) + ' NOCHECK CONSTRAINT ALL' AS '--Code to disable constraints temporarily'
			END

		PRINT 'GO'
	END

PRINT ''
PRINT 'PRINT ''Inserting values into ' + '[' + RTRIM(COALESCE(@target_table,@table_name)) + ']' + ''''


--All the hard work pays off here!!! You'll get your INSERT statements, when the next line executes!
EXEC (@Actual_Values)

PRINT 'PRINT ''Done'''
PRINT ''


IF @disable_constraints = 1 AND (OBJECT_ID(QUOTENAME(COALESCE(@owner,USER_NAME())) + '.' + @table_name, 'U') IS NOT NULL)
	BEGIN
		IF @owner IS NULL
			BEGIN
				SELECT 	'ALTER TABLE ' + QUOTENAME(COALESCE(@target_table, @table_name)) + ' CHECK CONSTRAINT ALL'  AS '--Code to enable the previously disabled constraints'
			END
		ELSE
			BEGIN
				SELECT 	'ALTER TABLE ' + QUOTENAME(@owner) + '.' + QUOTENAME(COALESCE(@target_table, @table_name)) + ' CHECK CONSTRAINT ALL' AS '--Code to enable the previously disabled constraints'
			END

		PRINT 'GO'
	END

PRINT ''
IF (@IDN <> '')
	BEGIN
		PRINT 'SET IDENTITY_INSERT ' + QUOTENAME(COALESCE(@owner,USER_NAME())) + '.' + QUOTENAME(@table_name) + ' OFF'
		PRINT 'GO'
	END

PRINT 'SET NOCOUNT OFF'


SET NOCOUNT OFF
RETURN 0 --Success. We are done!
END

GO

PRINT 'Created the procedure'
GO


--Mark procedure as system object
EXEC sys.sp_MS_marksystemobject sp_generate_inserts
GO

PRINT 'Granting EXECUTE permission on sp_generate_inserts to all users'
GRANT EXEC ON sp_generate_inserts TO public

SET NOCOUNT OFF
GO

PRINT 'Done'

Form style dialogs

When you are creating your user interfaces you often want to produce a pop up form.  The code below is not perfect in that when you close the form it asks you if you want to save but it is workable:

ReportUnderConstruction[] := NotebookPut[Notebook[{
    Cell["Report under construction", "Text"]
    }]]

testForm[] := DynamicModule[{},
  Column[{
    TextCell["Form", "Section"],
    Text@TextCell["Reconciliation 2010-08-24", "Subsection"],
    Text@TextCell["Sample controls to illustrate a dialog box.",
      "Text", FontColor -> Darker@Blue],
    Spacer[10],
    Button[Style["Show Report", FontFamily -> "Helvetica"],
     ReportUnderConstruction[]],
    Spacer[10],
    Button[Style["Reset Report", FontFamily -> "Helvetica"],
     ReportUnderConstruction[]],
    Spacer[10]
    }]]

Button["Form", nb = NotebookPut[Notebook[{
     Cell["testForm[]", "Input", CellOpen -> False]
     }]];
SelectionMove[nb, Next, Cell];
SelectionEvaluateCreateCell[nb]]

This looks like this:

When you click on the button you get the pop up form:

Those buttons then produce a very simple report:

Mathematica Initialization cell

I have been trying to develop little Mathematica applications.  A misconception I have had is that an initialization cell  will run when you open the notebook.  However I don’t think it runs until you either execute another cell when you are then asked to run all initialization cells or Evaluate Initialization Cells from a menu.  However with Player Pro I don’t think it is posible to start an application without clicking once.

Dynamic cells I don’t think help as you still get a “Dynamic Content Warning” dialog box which is offputting to naive users.

I am looking to do a double bootstrap deployment, the first bootstrap gives you a very simple loader notebook which you can deploy on Mathematica Player Pro.  You open it eg from File Explorer click the button and you have your application ready to go.  This is a very simple application.

Then you can add other options eg deploying your files to where you need them etc.  I plan to cover later a more complicated example with code in modules and a good user interface using tabbed windows.  Then you need to compress the packages which can all be done with Mathematica. (The first time I did this I made the mistake of unbundling the definitions of report and myProgram so that they didn’t work in the loader.  When I clicked the button on the loader they hadn’t been defined so nothing happened.*)

To save anybody the effort of typing I have the text of the above here s:

myLoader = Notebook[{
    Cell[Button["My Loader",
      NotebookPut[Notebook[{Cell["BootStrap Application"]}]]], "Text"],
    Cell[BoxData[ButtonBox["\<\"Run the Program\"\>",
       Appearance -> Automatic, ButtonFunction :>
        ((*These definitions need to be executed by the click of the \
button to make them available later*)
         report = Notebook[{Cell["Simplest report", "Text"]}];
         myProgram = Notebook[{
            Cell[Button["My Program",
              NotebookPut[Notebook[{Cell["BootStrap Application"]}]]],
              "Text"],
            Cell[BoxData[ButtonBox["\<\"Run the Report\"\>",
               Appearance -> Automatic, ButtonFunction :>
                (
                 NotebookPut[report]
                 ), Evaluator -> Automatic, Method -> "Preemptive"]],
             "Output"]
            }];
         NotebookPut[myProgram];
         NotebookClose[] (*Loader's job is done and it closes to
         prevent any errors corrupting it*)
         ), Evaluator -> Automatic, Method -> "Preemptive"]], "Output"]
    }];

Button["Create Loader",
nb = NotebookPut[myLoader];
NotebookSave[nb, NotebookDirectory[] <> "Loader.nb"]
]

Mathematica Run and spaces

On Windows I have been trying to interface to another program.  This is due to the PlayerPro not supporting the .NET interface so you can’t do COM object manipulation.  So I am putting any of that code into an exe built by  Autoit and then want Mathematica to call it with variable parameters.

However  I have had real trouble using the Run[] command to run a progam which has a command and a parameter with a filename with spaces in it.

Run[“\”F:\\A dir\\test.exe\" “\”F:\\A dir\\data\"”]

so my work around is to put the command in a batch file Run.bat and then run:

Run[“\”F:\\A dir\\run.bat\"”]

Which is irritating but works.

I used the following to build the command file:

batchRun[workingDir_, command_] := Module[{fn, str},
  fn = workingDir <> "Run.bat";
  If[FileExistsQ[fn], DeleteFile[fn]];
  str = OpenWrite[fn];
  WriteString[str, command];
  Close[str];
  Run["\"" <> fn <> "\""]
  ]

Mathematica Player Pro deployment process

Starting with a working notebook and assuming that you are working in workbench.  The aim is then to first convert this into very simple notebook with all the gui code in a gui package.  Then to combine all these elements into an installable exe file using InnoSetup for deployment on a machine with PlayerPro installed or just copy them across to your destination.

1) Convert the Gui cells to initialisation cells.  This then saves the code to .m package.

2) Supposing you want to keep the template separate then Rename the saved notebook to something else eg _template.  Rename the saved .m file as smethingGUI.m and the template.

3)Edit somethingGUI.m into a package file with a single function runGUI[]. 

a) Whereas before you might have explicit dependencies in the code eg Needs{moduleX`]  this can now be moved into the begin package dependency list:

BeginPackage["somethng`",  {"moduleX`"}]

b) Any references to global variables will now need to be prefixed with Global` now that they are embedded in a private part of the package.

4) Create a new notebook with the single cell and interface

If[Fold[Or, False,
   StringMatchQ[$Path, ___ ~~ "MathematicaPlayerPro" ~~ ___]],
  Needs[# <> "`", NotebookDirectory[] <> # <> ".mx"] &,
  Needs[# <> "`"] &] /@ {"moduleX”, 
  "somethingGUI"}; somethingGUI`runGUI[]

5) Open this notebook with the Mathematica front end  and run it.  It should work, eg display front end and then allow you to interact with the front end.

6) Edit the Gui code for the button and modify  like this

Dynamic@Button[Style["Run report",FontFamily->"Helvetica"],
      (

If[Fold[Or, False,
   StringMatchQ[$Path, ___ ~~ "MathematicaPlayerPro" ~~ ___]],
  Needs[# <> "`", NotebookDirectory[] <> # <> ".mx"] &,
  Needs[# <> "`"] &] /@ {"moduleX”, 
  "somethingGUI"};

        something`createReport[thisDate];
      ),Enabled->fileExists
    ]

(The fileExists is a dynamic variable that depends on a file test depdning on what the user puts in.  If the file doesn’t exsit the buton is not enabled) (This is a bit of kludge but seems to work.  When you save a result it sees to save partial but not all linked files so then using a Needs in the button procedure loads the path but not quite quickly enough so you need to use complete references.  you need to open the file in the front end and execute the code then make code option not open and then save the notebook.  You now get a blank notebook that opens and you can press buttons. on it.

7)  Build a build and deploy module that actually compresses the files and then deploys them to the test machine.

8) When it runs I still have the run dynamic content and run the initialistation bxes to click. but then it does start up

The next stage is to put this all together as a set of sample files.

Mathematica Time Series

I have been working on a general data type for the manipulation of time series data.  It still needs some work on it although I have used it for odd jobs.  The time series based on vectors is much faster than the general lists.

you can download the Dates.m file here

There is also a simple test framework which I will rewrite in the future now that I am familiar with the mUnit test framework in Workbench which I like a lot.

This is loosely based on a sample from  Copyright 2005, Kim C. Border Package 0.8.  He has allowed me to release the derived work.

Mathematica testing notebook reports

I am just coming to grips with creating notebooks (reports) in the kernel and for testing the report.  When testing with MUnit there is no front end so it seems that all the Notebook manipulation commands such as:

    nb = CreateDocument[]

    nb = NotebookPut[]

don’t work.  So my work around is to test my own notebook.  This can be turned into an actual workbook easily on a FrontEnd eg:

In[3]:= nb = Notebook[{}]

Out[3]= Notebook[{}]

In[6]:= AppendNotebook[nb_, expr_] :=
Notebook[Append[nb[[1]], expr]]; nb =
AppendNotebook[nb, Cell["Hello", "Subsection"]]

Out[6]= Notebook[{Cell["Hello", "Subsection"]}]

In[8]:= NotebookPut[nb]

Then you can add a grid box – I have adapted a version here which produces a box even if all the tables are not quite the right length as I would rather have a grid when the data is wonky than not:

writeNotebookGrid[nb_, body_, headerList_] :=
Module[{headings, itemsBody, cols, useBody, result},
  result = AppendNotebook[nb, Cell["Table", "Subsection"]];
  If[Depth[body] < 3, useBody = {{"Body parameter not deep enough"}},
   useBody = body];
  cols = Max[Length[headerList], Length[#] & /@ useBody];
  headings =
   Map[StyleBox[#, FontFamily -> "Times", FontWeight -> "Bold",
      FontColor -> RGBColor[0.5, 0, 0.3]] &, {PadRight[headerList,
      cols, ""]}, {2}];
  itemsBody = Join[headings, PadRight[#, cols, ""] & /@ useBody];
  result =
   AppendNotebook[result,
    Cell[BoxData[
      GridBox[itemsBody, GridFrame -> True, RowLines -> True,
       ColumnLines -> True]], "Text"]];
  Return[result]
  ]

nb = writeNotebookGrid[nb, {{1, 2}, {2, 3}}, {A, B, C}]

Which gives you a little table in your report like this:

Adding graphs to your plot is done like this:

ab = AppendNotebook[nb,
  Cell[BoxData[ToBoxes[Plot[Tan[x], {x, 0, \[Pi]}]], ""],
   "Text"]]; NotebookPut[ab]

The syntax is a bit fidly but will build you a notebook like this:

The great thing is that once you have these primitives you can quickly iterate through large data sets and produce detailed reports.  Especially if you spend some time on the graphs with annotations and labels.  Mathematica 7 has improved legends over Mathematica 6.

Mathematica debugger line by line

I find that it seems that the Mathematica debugger on the workbench gets confused about stepping line  by line (F6 Step over) once you have stepped into (F5 Step Into) another function.  My work around is to set another breakpoint in the second function you are debugging.

Mathematica package hell

I accidentally created a circular dependency with a Package A Needs Package B which Needs Package C which needs Package A.

Having done that Package A couldn’t access Package B routines even though it correctly need them.  The full form did work eg PackageB`function[].

It is something to be careful of but there is no particular help from the compiler or workbench.  It should be possible to write a package dependency tree program quite easily.

Mathematica Debugger Traps

When I first started using WorkBench 2.0 and Mathematica 7.0.1 I found the operation of the debugger flaky.  However I have identified a number of issues have helped me.

1 My problem was due to using a global connection in the module:

conn=OpenSQLConnection[…

This then prevents the debugger working.  I have now reworked my code so that I don’t use this type of connection. 

I have tested whether it is expensive to open a SQL connection on every call or if you do it just once for a group of calls.  Doing 10 simple queries took 1.7 seconds if the connection was opend and closed every time and ca 1 second if it was only opened once.  So for the generation of reports I am going to avoid the considerable work involved in doing two headers and wait until I can generate them automatically.

2 Timing.  You have to wait until the Workbench has finished loading.  This takes a number of seconds and you can easily start executing code in the opened notebook first.  If you do that the bottom right of the workbench screen will look like this:

The input number will be 2 rather 7 or 8 which is normal if the debugger is going to work.

3 I tried SVN addin to the workbench and that was a bad idea.  I had to uninstall and reinstall workbench to get back a working version.  I saw a post where Wolfram are working on the SVN version so I hope that comes through.

4 In the debug screen I make sure I delete other debug activities before starting a new debugging session.

5 Be good about default directories.  I tried a different directory for the module and the debugger wouldn’t breakpoint at it.  Moving it to the normal directory worked fine.

Formatting tables in Mathematica reports,

I have come across someone who is doing something very similar in producing formatted reports:

http://www.scientificarts.com/formatting/formatting.html

It appears to be difficult to use TableForm when generating reports in created notebook reports and in the above example they have a work around.

Creating Monkey reports in Mathematica

What I am after is a simple way to generate reports or actually carry out work based on some user input which can be carried out in Mathematica Pro.  I have struggled with an apparent interaction between long runnng sql queries and Dynamic Module which means that the execution has been unreliable when using Dynamic modules.

I created a demo report that allows you on Mathematica to push a button, request some input and generate a report .  The issue is that does not work very nicely in Player Pro as although there is a nice button to press you need to evaluate all the code.

I have now converted this into a number of files and successfully deployed to a Mathematica Player Pro.  i have stored the files in google docs so they can be downloaded.

The demo files are:

• Button pressing file
• Button pressing package
• Encrypted button pressing package
• Code to create the encrypted package.

Having got a working notebook I did the following:

1. Converted the library code to initialisation cells.  This created an initialisation package.
2. Converted the auto saved initialisation package “report.m” to a package by adding BeginPackage,usage info for main function, Begin[`private`],End and End package.
3. Convert the package to an encrypted package using the helper.  You need an encrypted needs when running on Player Pro
4. Converted the report to just a single button with no extra code.  It needs the encrypted package.  One trick is to hide the code by removing the Cell –>Cell Properties open flag.
5. Copy the encrypted packaged and button file to another system and I have a working tool.

Good news.

Options for connecting Mathematica to a MS SQL server

The following is just an example of connecting to a SQL database (actual names changed slightly)  Also showing the slightly naughty habit of using the user sa.

In[1]:= Needs["DatabaseLink`"]

In[2]:= conn =
OpenSQLConnection[JDBC["Microsoft SQL Server(jTDS)", "MyServer"],
  "Catalog" -> "MyDemo", "Username" -> "sa",
  "Password" -> "RubyPane"]

Out[2]= SQLConnection[2, "Open", "Catalog" -> "MyServer",
"TransactionIsolationLevel" -> "ReadCommitted"]

This is a useful link for getting SQLExpress to work (basically don't try the integrated security):

http://softwaresalariman.blogspot.com/2007/04/jdbc-to-sql-server-express.html

Which gets me to:

s[] := OpenSQLConnection[
  JDBC["Microsoft SQL Server(jTDS)",
   "127.0.0.1:1433/Test;user=sa;password=sa"],
  "Catalog" -> "TestTercero", "User" -> "sa", "Password" -> "sa"]